

;COMMENTS
; Flag 1 is OFF at start of game and ON otherwise
; Flag 2 is ON if lantern is ON and OFF otherwise
; Flag 3 is ON if Cooler and beer are warm
; Flag 4 is ON if NOZEGLOZE condition is true
; Flag 5 is ON if it is snowing and OFF otherwise
; Variable 1 will count down the life of the lantern
; Variable 2 count of turns at South Pole without a parka
; Variable 3 count of number of turns that Penguin has been following player
; Counter 1 counts turns since cooler was opened
; Counter 2 counts turns since snowflake fell
; Counter 3 counts turns since thermometer was put in cooler


; ANY COMMANDS -- Considered for ANY combination of words -- i.e., each turn


COMMAND ANY
FlagOFF 1 (* First turn of game *)
SetVariableTo 1 50 (* battery life set to 50 turns *)
TurnFlagON 1 (* initialization process is over *)
END_COMMAND

COMMAND ANY
FlagOFF 3 (* Cooler is still cold *)
CounterEquals 3 3 (* The thermometer was put in cooler three turns ago. *)
SwapLocations 240 244 (* Swap for COLD thermometer *)
PutInCurrentRoom 241 (* snow flake *)
TurnCounterON 2 (* Count number of turns since snow flake fell *)
PrintMessage 61 (* The mercury in the thermometer has fallen *)
TurnFlagON 5 (* It is snowing *)
PlusScore 10
END_COMMAND

COMMAND ANY
CounterEquals 2 10 (* Snow flake fell ten turns ago. *)
Present 241 (* Snow flake is here *)
PrintMessage 62 (* The first snowflake melted! *)
MinusScore 10
END_COMMAND

COMMAND ANY
CounterEquals 2 10 (* Snow flake fell ten turns ago. *)
Destroy 241 (* Snow flake melts *)
MinusScore 10
END_COMMAND

COMMAND ANY
NOT AtLocation 61 (* starting room *)
AtLocationGT 25 (* South pole *)
Present 301 (* Percival is here *)
Present 226 (* Egbert's Diary *)
PrintMessage 55 (* Percival just stole Egbert's diary. *)
Destroy 226 (* It's now gone *)
MinusScore 10
END_COMMAND

COMMAND ANY
NOT AtLocation 61 (* starting room *)
AtLocationGT 25 (* At South pole *)
NOT IsWearing 207 (* NOT wearing parka *)
AddToVariable 2 1 (* Increment count of times at South Pole without a parka *)
VariableEquals 2 4 (* Four turns without parka *)
PrintMessage 72 (* You freeze to death. *)
KillPlayer
MinusScore 10
DoneWithTurn
END_COMMAND

COMMAND ANY
FlagOFF 3 (* Cooler and beer are cold *)
CounterEquals 1 10 (* ten turns since first time cooler opened *)
SwapLocations 230 231 (* Swap warm beer for cold beer *)
TurnFlagON 3 (* Cooler and beer are now warm *)
Present 229 (* cooler *)
PrintMessage 44 (* The cooler has warmed up a bit. *)
MinusScore 10
END_COMMAND

COMMAND ANY
FlagON 2 (* lantern is ON *)
SubtractFromVariable 1 1 (* decrement battery life counter *)
END_COMMAND

COMMAND ANY
FlagON 2 (* lantern is ON *)
Present 242 (* ON lantern is here *)
VariableGT 1 0 (* At least one more turn for battery life *)
VariableLT 1 11 (* Less than ten more turns for battery life *)
PrintMessage 34 (* Your nifty lantern is flickering on and off. *)
END_COMMAND

COMMAND ANY
FlagON 2 (* lantern is ON *)
VariableEquals 1 0 (* Last turn for battery life *)
TurnFlagOFF 2 (* Lantern is OFF for good *)
SwapLocations 242 243 (* Swap for DEAD lantern *)
Present 242 (* ON lantern is here *)
PrintMessage 35 (* Your nifty lantern flickers and goes off. *)
END_COMMAND

COMMAND ANY
Present 301 (* Percival is here *)
AddToVariable 3 1 (* Increment count of turns Percival has been following *)
AddToGroup 301 (* Have Percival follow player *)
VariableEquals 3 8 (* Has been following for 8 turns *)
OR
VariableEquals 3 17 (* Has been following for 17 turns *)
PrintMessage 78 (* So buzz off! *)
END_COMMAND

COMMAND ANY
Present 301 (* Percival is here *)
Chance 15 (* 15% chance *)
PrintMessage 80 (* Percival swims around and comes back *)
END_COMMAND

COMMAND ANY
Present 301 (* Percival is here *)
Chance 20 (* 20% chance *)
PrintMessage 87 (* Percival Penguin kicked you in the shin. *)
END_COMMAND

COMMAND ANY
Present 301 (* Percival is here *)
VariableGT 3 19 (* Has been following for 20 turns or more *)
NOT AtLocation 37 (* Percival's "home" floe *)
PrintMessage 79 (* Percival throws snowball and leaves. *)
SendToRoom 301 37 (* Send Percival "home" *)
RemoveFromGroup 301 (* Have Percival stop following player *)
SetVariableTo 3 0 (* Reset following counter to 0 *)
END_COMMAND

COMMAND ANY
Present 301 (* Percival is here *)
VerbIsDirection (* Player trying to leave current floe *)
Chance 15 (* 15% chance *)
NOT AtLocation 37 (* Percival's "home" floe *)
RandomMessage 81 86 (* Percival leaves in random direction. *)
SendToRoom 301 37 (* Send Percival "home" *)
RemoveFromGroup 301 (* Have Percival stop following player *)
SetVariableTo 3 0 (* Reset following counter to 0 *)
END_COMMAND


;COMMANDS -- Considered only for specific combinations of words


;ENTER COMMAND

COMMAND ENTER MIRROR
FlagON 5 (* It is snowing *)
PrintMessage 71 (* Nothing happens. *)
DoneWithTurn
END_COMMAND

COMMAND ENTER MIRROR
Present 201 (* Shinny Mirror *)
GoToRoom 26 (* At the ice door -- At the South Pole *)
PrintMessage 69 (* You are temporarily stunned by a flash of blinding light. *)
PrintMessage 70 (* The hair at the back of your neck stands straight up. *)
DoneWithTurn
END_COMMAND

COMMAND ENTER MIRROR
AtLocation 26 (* At the ice door -- At the South Pole *)
GoToRoom 2 (* Bunkhouse *)
PrintMessage 69 (* You are temporarily stunned by a flash of blinding light. *)
DoneWithTurn
END_COMMAND

COMMAND ENTER ANY
RandomMessage 1 6 (* "Bizarre" message. *)
DoneWithTurn
END_COMMAND

;PUT COMMANDS

COMMAND PUT POINSETTIA IN BLENDER
Present 233 (* Blender *)
Present 235 (* Real Poinsettia *)
Destroy 235 (* Real Poinsettia *)
SendToRoom 236 233 (* Put juice in blender *)
PrintMessage 65 (* It is now juice *)
PlusScore 25
DoneWithTurn
END_COMMAND

COMMAND PUT SNOW FLAKE IN BLENDER
Present 233 (* Blender *)
Present 241 (* Snow flake *)
IsLocated 236 233 (* The juice is in blender *)
PrintMessage 66 (* It is now juice *)
TurnFlagON 4 (* NOZEGLOZE is ON *)
PlusScore 25
DoneWithTurn
END_COMMAND

COMMAND PUT SNOW FLAKE IN ANY
Present 241 (* Snow flake *)
PrintMessage 62 (* The snow flake melts *)
Destroy 241
DoneWithTurn
END_COMMAND

COMMAND PUT THERMOMETER IN COOLER
Present 240 (* Thermometer *)
Present 229 (* Cooler *)
TurnCounterON 3 (* Count number of turns since thermometer put in cooler *)
END_COMMAND

COMMAND PUT HAT ON SNOWMAN
Present 234 (* Silk hat *)
Present 306 (* ordinary snowman *)
SwapLocations 306 300 (* Snowman turns into Frosty *)
PrintMessage 49 (* Must have been some magic in that old silk hat! *)
Destroy 234 (* Silk hat now is part of Frosty -- on his head *)
PlusScore 25
DoneWithTurn
END_COMMAND

COMMAND PUT ANY ON SNOWMAN
Present 306 (* ordinary snowman *)
OR
Present 300 (* Frosty the snowman *)
PrintMessage 50 (* What would a snowman want with that? *)
DoneWithTurn
END_COMMAND

;GIVE COMMANDS

COMMAND GIVE STRING TO SANTA
Present 302 (* Santa is here *)
Present 216 (* String is here *)
Destroy 216 (* It's now on Santa *)
SwapLocations 302 303 (* Santa sports a green mitten string *)
PrintMessage 63 (* Santa take string and uses it as a belt *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO SANTA
Present 302 (* Unstrung Santa is here *)
OR
Present 303 (* Stringed Santa is here *)
PrintMessage 64 (* Santa shakes his head and says 'I don't need that.' *)
DoneWithTurn
END_COMMAND

COMMAND GIVE HAT TO SNOWMAN
Present 234 (* Silk hat *)
Present 306 (* ordinary snowman *)
SwapLocations 306 300 (* Snowman turns into Frosty *)
PrintMessage 49 (* Must have been some magic in that old silk hat! *)
Destroy 234 (* Silk hat is now part of Frosty -- on his head *)
PlusScore 25
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO SNOWMAN
Present 306 (* ordinary snowman *)
PrintMessage 50 (* What would a snowman want with that? *)
DoneWithTurn
END_COMMAND

COMMAND GIVE POINSETTIA TO SNOWMAN
Present 221 (* You have the poinsettia to give *)
Present 300 (* Frosty the snowman *)
PrintMessage 52 (* Frosty accepts your gift graciously. *)
PrintMessage 53 (* He turns them into real flowers. *)
SwapLocations 221 235 (* Swap for real poinsettia *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO SNOWMAN
NOUNPresent (* You have it to give *)
Present 300 (* Frosty the snowman *)
PrintMessage 52 (* Frosty accepts your gift graciously. *)
DestroyNOUN (* It's now gone *)
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO PERCIVAL
NOUNPresent (* You have it to give *)
Present 301 (* Percival is here *)
PrintMessage 52 (* Percival grabs the $NOUN$ and stuffs it in his tuxedo pocket. *)
DestroyNOUN (* It's now gone *)
DoneWithTurn
END_COMMAND

COMMAND GIVE JUICE TO RUDOLPH
Present 236 (* Poinsettia Juice *)
FlagON 4 (* NOZEGLOZE flag is ON *)
PrintMessage 56 (* It does the trick ... You win! *)
Destroy 236
PlusScore 50
WinGame
DoneWithTurn
END_COMMAND

COMMAND GIVE JUICE TO RUDOLPH
Present 236 (* Poinsettia Juice *)
FlagOFF 4 (* NOZEGLOZE flag is OFF *)
PrintMessage 57 (* You screwed up and lose game! *)
Destroy 236
MinusScore 50
EndGame
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO RUDOLPH
NOUNPresent (* You have it to give *)
PrintMessage 58 (* Rudolph doesn't appear to be interested. *)
DoneWithTurn
END_COMMAND

;TAKE or GET COMMANDS

COMMAND GET PAPER
AtLocation 5 (* Gift wrap room *)
PrintMessage 22 (* Sorry, but you don't have time to mess with the $NOUN$.*)
DoneWithTurn
END_COMMAND

COMMAND TAKE SNOW FLAKE
Present 241 (* It is here *)
PrintMessage 60 (* It's starting to snow EVERYWHERE! *)
GetNOUN (* You wanted it -- you got it. *)
DoneWithTurn
END_COMMAND

;DROP COMMANDS

COMMAND DROP ANY
NOUNPresent (* You have it to drop *)
Present 301 (* Percival is here *)
PrintMessage 52 (* Percival grabs the $NOUN$ and stuffs it in his tuxedo pocket. *)
DestroyNOUN (* It's now gone *)
DoneWithTurn
END_COMMAND

;The above meta-command will make if very difficult to use the traditional
;maze mapping technique of dropping items in various locations.

;MAKE COMMANDS

COMMAND MAKE SNOWMAN
NOT AtLocation 61 (* starting room *)
AtLocationGT 25 (* South pole *)
PrintMessage 46 (* It's too cold here to build a snowman here.
DoneWithTurn
END_COMMAND

COMMAND MAKE SNOWMAN
NOT AtLocation 21 (* On the runway *)
PrintMessage 47 (* You can't build a snowman here. *)
DoneWithTurn
END_COMMAND

COMMAND MAKE SNOWMAN
IsNowhere 306 (* Ordinary snowman *)
IsNowhere 300 (* Frosty the snowman *)
AtLocation 21 (* On the runway *)
PrintMessage 48 (* Okay, you build a snowman. *)
PutInCurrentRoom 306 (* Ordinary snowman *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND MAKE ANY
PrintMessage 22 (* Don't dilly dally! *)
DoneWithTurn
END_COMMAND

;DRINK COMMANDS

COMMAND DRINK JUICE
Present 236 (* Juice *)
PrintMessage 73 (* Dumb! Dumb! Dumb! *)
Destroy 236
DoneWithTurn
END_COMMAND

COMMAND DRINK BEER
Present 231 (* Warm beer *)
PrintMessage 45 (* YECH!!!  You decide not to drink it. *)
DoneWithTurn
END_COMMAND

COMMAND DRINK BEER
Present 230 (* Cold beer *)
PrintMessage 54 (* Cold beer!!!  You drink them all. *)
SwapLocations 230 232 (* Swap beer for empty bottles *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND DRINK ANY
RandomMessage 1 6 (* "Bizarre" message *)
DoneWithTurn
END_COMMAND

;READ COMMANDS

COMMAND READ DIARY
Present 226 (* Santa's Diary *)
RandomMessage 25 33 (* randomly display a page from the diary *)
DoneWithTurn
END_COMMAND

;UNLOCK COMMANDS

COMMAND UNLOCK MIDDLE DRAWER WITH KEY
Present 210 (* Brass key *)
Present 203 (* Middle Drawer *)
ObjectIsNumber 210 (* Brass key *)
NOUNIsNumber 203 (* Middle Drawer *)
SwapLocations 210 211 (* Swap for broken key *)
PrintMessage 59 (* The brass key breaks off in lock *)
UnLockIt 203 (* unlock the middle drawer *)
DoneWithTurn
END_COMMAND

;OPEN COMMANDS

COMMAND OPEN COOLER
Present 229 (* cooler *)
CounterEquals 1 0 (* first time cooler opened *)
TurnCounterON 1 (* start counter for number of turns since cooler opened *)
END_COMMAND

COMMAND OPEN DIARY
Present 226 (* Santa's Diary *)
RandomMessage 25 33 (* randomly display a page from the diary *)
DoneWithTurn
END_COMMAND

COMMAND OPEN DOOR
AtLocation 27 (* At the ice door *)
GoToRoom 28 (* Inside, near door *)
PrintMessage 88 (* You enter the room in the hill. *)
DoneWithTurn
END_COMMAND

COMMAND OPEN DOOR
AtLocation 28 (* Inside, near door *)
GoToRoom 27 (* At the ice door *)
PrintMessage 89 (* You leave the room in the hill. *)
DoneWithTurn
END_COMMAND

;SIT COMMANDS

COMMAND SIT ANY
AtLocation 6 (* Santa's Office *)
PrintMessage 24 (* You don't have time to sit down! *)
DoneWithTurn
END_COMMAND

;LIGHT COMMANDS

COMMAND LIGHT LANTERN
Present 205 (* OFF lantern is here *)
TurnFlagON 2 (* lantern is now ON *)
SwapLocations 242 205 (* Swap for ON lantern *)
PrintMessage 36 (* Your lantern is now on. *)
DoneWithTurn
END_COMMAND

COMMAND LIGHT LANTERN
Present 242 (* ON lantern is here *)
PrintMessage 38 (* The lantern is already on. *)
DoneWithTurn
END_COMMAND

COMMAND LIGHT LANTERN
Present 243 (* DEAD lantern is here *)
PrintMessage 39 (* Sorry, but this lantern has had it. *)
DoneWithTurn
END_COMMAND

;EXTINGUISH COMMANDS

COMMAND EXTINGUISH LANTERN
Present 242 (* ON lantern is here *)
TurnFlagOFF 2 (* lantern is now OFF *)
SwapLocations 242 205 (* Swap for OFF lantern *)
PrintMessage 37 (* Your lantern is now off. *)
DoneWithTurn
END_COMMAND

COMMAND EXTINGUISH LANTERN
Present 243 (* DEAD lantern is here *)
OR
Present 205 (* OFF lantern is here *)
PrintMessage 40 (* Sorry, but this lantern is already OFF. *)
DoneWithTurn
END_COMMAND

;TURN COMMANDS

COMMAND TURN LANTERN
PrintMessage 41 (* Please use LIGHT LANTERN and EXTINGUISH LANTERN. *)
DoneWithTurn
END_COMMAND

;WEAR COMMANDS

COMMAND WEAR MITTENS
Present 214 (* Left mitten is here *)
Present 215 (* Right mitten is here also *)
PrintMessage 90 (* You put on the right mitten *)
PrintMessage 91 (* You put on the left mitten *)
DoneWithTurn
END_COMMAND

COMMAND WEAR MITTENS
Present 214 (* Left mitten is here *)
PrintMessage 91 (* You put on the left mitten *)
DoneWithTurn
END_COMMAND

COMMAND WEAR MITTENS
Present 215 (* Right mitten is here *)
PrintMessage 90 (* You put on the right mitten *)
DoneWithTurn
END_COMMAND

;TIE and UNTIE COMMANDS

COMMAND UNTIE MITTENS
Present 213 (* Tied mittens are here *)
SwapLocations 213 214 (* Swap left mitten for tied pair *)
SendToItem 215 214 (* Move right mitten also *)
SendToItem 216 214 (* Move string also *)
PrintMessage 42 (* You untie the mittens *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND UNTIE STRING
Present 213 (* Tied mittens are here *)
SwapLocations 213 214 (* Swap left mitten for tied pair *)
SendToItem 215 214 (* Move right mitten also *)
SendToItem 216 214 (* Move string also *)
PrintMessage 42 (* You untie the mittens *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND TIE MITTENS
Present 216 (* string is here *)
PrintMessage 43 (* You can't do it. *)
DoneWithTurn
END_COMMAND

COMMAND TIE STRING TO MITTENS
Present 216 (* string is here *)
PrintMessage 43 (* You can't do it. *)
DoneWithTurn
END_COMMAND

COMMAND TIE ANY
PrintMessage 22 (* Sorry, but you don't have time to mess with the $NOUN$.*)
DoneWithTurn
END_COMMAND

;TALK and ASK COMMANDS

COMMAND TALK TO ELF
PrintMessage 22 (* Sorry, but you don't have time to mess with the $NOUN$.*)
DoneWithTurn
END_COMMAND

COMMAND ASK ELF
PrintMessage 22 (* Sorry, but you don't have time to mess with the $NOUN$.*)
DoneWithTurn
END_COMMAND

;EXAMINE COMMANDS

COMMAND EXAMINE DRAWER
AtLocation 6 (* Santa's Office *)
PrintMessage 23 (* It has an ornate gold lock *)
DoneWithTurn
END_COMMAND
  
COMMAND EXAMINE PAPER
AtLocation 5 (* Gift wrap room *)
DescribeThing 220 (* describe paper, etc....*)
DoneWithTurn
END_COMMAND

COMMAND EXAMINE ELF
DescribeThing 305 (* From where you're standing you can't see the elf's face. *)
DoneWithTurn
END_COMMAND

COMMAND EXAMINE PATH
PrintMessage 11 (* The path disappears in the fog. *)
DoneWithTurn
END_COMMAND

;LOOK COMMANDS

COMMAND LOOK ANY
AtLocation 61 (* In octagonal room *)
PrintMessage 21 (* You can barely turn around in here. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 3 (* Elves' Closet *)
PrintMessage 7 (* This closet seems very familiar. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 4 (* Santa's Workshop *)
PrintMessage 8 (* Lengthy description of workshop *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 5 (* Gift Wrapping Room *)
PrintMessage 9 (* What are you looking for?  Need to wrap a gift? *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 6 (* Santa's Office *)
PrintMessage 10 (* The desk and the computer look interesting *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 9 (* Outside the workshop *)
PrintMessage 12 (* The fog is so dense you can only see a few metres. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 22 (* In the reindeer barn *)
PrintMessage 13 (* You notice an enormous set of doors leading northeast. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 27 (* Outside near the door *)
PrintMessage 14 (* The door is closed. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 28 (* Inside near the door *)
PrintMessage 15 (* The door is closed. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 29 (* Inside the room in the hill *)
PrintMessage 16 (* Another description of room. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 30 (* Inside the narrow passage *)
PrintMessage 17 (* You don't discover anything new about the passage. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 31 (* Dead End *)
PrintMessage 18 (* You discover a piece of lined paper. *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 32 (* On ice plain1 *)
OR
AtLocation 33 (* On ice plain2 *)
OR
AtLocation 34 (* On ice plain3 *)
PrintMessage 19 (* Long, poetic description of ice plain *)
DoneWithTurn
END_COMMAND

COMMAND LOOK ANY
AtLocation 45 (* In the crystal ice garden *)
PrintMessage 20 (* a herd of reindeer stampeded through here. *)
DoneWithTurn
END_COMMAND

;ATTACK COMMANDS

COMMAND ATTACK ANY
PrintMessage 67 (* Such behaviour would be most unbecoming of a Christmas elf *)
MinusScore 10
DoneWithTurn
END_COMMAND

;HELP COMMANDS

COMMAND HELP ANY
PrintMessage 68 (* That's right.  You're here to help Santa. *)
DoneWithTurn
END_COMMAND

;QUIT COMMANDS

COMMAND QUIT
PrintMessage 74 (* Do you really want to quit? *)
PromptForYes (* Get YES or NO answer from keyboard *)
PrintMessage 75 (* Thank you for playing Elves! *)
EndGame (* OK, player entered YES -- so let's quit *)
DoneWithTurn
END_COMMAND

COMMAND QUIT
PrintMessage 76 (* I didn't think you really wanted to quit! *)
BlankLine
ReDirectTo LOOK
DoneWithTurn (* NO answer -- Ignore "Standard" AGT QUIT routine *)
END_COMMAND

;RUB COMMANDS

COMMAND RUB
NOUNPresent
PrintMessage 77 (* You $VERB$ the $NOUN$, but nothing happens. *)
DoneWithTurn
END_COMMAND

;SEARCH COMMANDS

COMMAND SEARCH THE TOP DRAWER
Present 202 (* Top drawer is here *)
NOUNIsNumber 202 (* The top drawer was specified in input *)
IsLocked 202 (* The top drawer is locked *)
PrintMessage 94 (* The $ADJECTIVE$ $NOUN$ is locked. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE TOP DRAWER
Present 202 (* Top drawer is here *)
NOUNIsNumber 202 (* The top drawer was specified in input *)
IsUnLocked 202 (* The top drawer is unlocked *)
OpenIt 202 (* Open the top drawer -- first *)
NOT SomethingInside 202 (* The top drawer is empty. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE TOP DRAWER
Present 202 (* Top drawer is here *)
NOUNIsNumber 202 (* The top drawer was specified in input *)
IsUnLocked 202 (* The top drawer is unlocked *)
OpenIt 202 (* Open the top drawer -- first *)
SomethingInside 202 (* The top drawer is NOT empty. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 202 (* Display contents of top drawer *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE MIDDLE DRAWER
Present 203 (* Middle drawer is here *)
NOUNIsNumber 203 (* The middle drawer was specified in input *)
IsLocked 203 (* The middle drawer is locked *)
PrintMessage 94 (* The $ADJECTIVE$ $NOUN$ is locked. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE MIDDLE DRAWER
Present 203 (* Middle drawer is here *)
NOUNIsNumber 203 (* The middle drawer was specified in input *)
IsUnLocked 203 (* The middle drawer is unlocked *)
OpenIt 203 (* Open the middle drawer -- first *)
NOT SomethingInside 203 (* The middle drawer is empty. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE MIDDLE DRAWER
Present 203 (* Middle drawer is here *)
NOUNIsNumber 203 (* The middle drawer was specified in input *)
IsUnLocked 203 (* The middle drawer is unlocked *)
OpenIt 203 (* Open the middle drawer -- first *)
SomethingInside 203 (* The middle drawer is NOT empty. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 203 (* Display contents of middle drawer *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE BOTTOM DRAWER
Present 204 (* Bottom drawer is here *)
NOUNIsNumber 204 (* The bottom drawer was specified in input *)
IsLocked 204 (* The bottom drawer is locked *)
PrintMessage 94 (* The $ADJECTIVE$ $NOUN$ is locked. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE BOTTOM DRAWER
Present 204 (* Bottom drawer is here *)
NOUNIsNumber 204 (* The bottom drawer was specified in input *)
IsUnLocked 204 (* The bottom drawer is unlocked *)
OpenIt 204 (* Open the bottom drawer -- first *)
NOT SomethingInside 204 (* The bottom drawer is empty. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE BOTTOM DRAWER
Present 204 (* Bottom drawer is here *)
NOUNIsNumber 204 (* The bottom drawer was specified in input *)
IsUnLocked 204 (* The bottom drawer is unlocked *)
OpenIt 204 (* Open the bottom drawer -- first *)
SomethingInside 204 (* The bottom drawer is NOT empty. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 204 (* Display contents of bottom drawer *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE DESK
Present 224 (* Santa's desk is here *)
NOUNIsNumber 224 (* Santa's desk was specified in input *)
IsLocked 224 (* Santa's desk is locked *)
PrintMessage 94 (* The $ADJECTIVE$ $NOUN$ is locked. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE DESK
Present 224 (* Santa's desk is here *)
NOUNIsNumber 224 (* Santa's desk was specified in input *)
IsUnLocked 224 (* Santa's desk is unlocked *)
OpenIt 224 (* Open Santa's desk -- first *)
NOT SomethingInside 224 (* Santa's desk is empty. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH THE DESK
Present 224 (* Santa's desk is here *)
NOUNIsNumber 224 (* Santa's desk was specified in input *)
IsUnLocked 224 (* Santa's desk is unlocked *)
OpenIt 224 (* Open Santa's desk -- first *)
SomethingInside 224 (* Santa's desk is NOT empty. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 224 (* Display contents of Santa's desk *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH RIGHT POCKET
Present 208 (* Right pocket of parka is here *)
NOUNIsNumber 208 (* Right pocket of parka was specified in input *)
OpenIt 208 (* Open right pocket -- first *)
NOT SomethingInside 208 (* Right pocket is empty. *)
PrintMessage 93 (* You open the $ADJECTIVE$ $NOUN$. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH RIGHT POCKET
Present 208 (* Right pocket of parka is here *)
NOUNIsNumber 208 (* Right pocket of parka was specified in input *)
OpenIt 208 (* Open right pocket -- first *)
SomethingInside 208 (* Right pocket is NOT empty. *)
PrintMessage 93 (* You open the $ADJECTIVE$ $NOUN$. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 208 (* Display contents of Right Pocket *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH LEFT POCKET
Present 209 (* Left pocket of parka is here *)
NOUNIsNumber 209 (* Left pocket of parka was specified in input *)
OpenIt 209 (* Open left pocket -- first *)
NOT SomethingInside 209 (* Left pocket is empty. *)
PrintMessage 93 (* You open the $ADJECTIVE$ $NOUN$. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH LEFT POCKET
Present 209 (* Left pocket of parka is here *)
NOUNIsNumber 209 (* Left pocket of parka was specified in input *)
OpenIt 209 (* Open left pocket -- first *)
SomethingInside 209 (* Left pocket is NOT empty. *)
PrintMessage 93 (* You open the $ADJECTIVE$ $NOUN$. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 209 (* Display contents of Left Pocket *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH COOLER
Present 229 (* Cooler is here *)
NOUNIsNumber 229 (* Cooler was specified in input *)
OpenIt 229 (* Open Cooler -- first *)
NOT SomethingInside 229 (* Cooler is empty. *)
PrintMessage 93 (* You open the $ADJECTIVE$ $NOUN$. *)
PrintMessage 95 (* The $ADJECTIVE$ $NOUN$ is empty. *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH COOLER
Present 229 (* Cooler is here *)
NOUNIsNumber 229 (* Cooler was specified in input *)
OpenIt 229 (* Open Cooler -- first *)
SomethingInside 229 (* Cooler is NOT empty. *)
PrintMessage 93 (* You open the $ADJECTIVE$ $NOUN$. *)
PrintMessage 96 (* The $ADJECTIVE$ $NOUN$ contains: *)
ShowContents 229 (* Display contents of Cooler *)
DoneWithTurn
END_COMMAND

COMMAND SEARCH ROOM
ReDirectTo LOOK
DoneWithTurn
END_COMMAND

COMMAND SEARCH ANY
RandomMessage 1 6 (* "Bizarre" message *)
DoneWithTurn
END_COMMAND

;SNEEZE COMMAND

COMMAND SNEEZE
AtLocation 61 (* staring room *)
PrintMessage 97 (* The entire room of elves echoes your sneeze...ACHHOOO! *)
DoneWithTurn
END_COMMAND

COMMAND SNEEZE
PrintMessage 98 (* God bless you! *)
DoneWithTurn
END_COMMAND

;DEBUG COMMAND

COMMAND DEBUG
ToggleFlag 0
DoneWithTurn
END_COMMAND

;DEBUG COMMAND

COMMAND DEBUG
ToggleFlag 0
DoneWithTurn
END_COMMAND

